GDScript basics

    Note

    Documentation about GDScript’s history has been moved to the Frequently Asked Questions.

    Example of GDScript

    Some people can learn better by taking a look at the syntax, so here’s a simple example of how GDScript looks.

    If you have previous experience with statically typed languages such as C, C++, or C# but never used a dynamically typed one before, it is advised you read this tutorial: GDScript: An introduction to dynamic languages.

    In the following, an overview is given to GDScript. Details, such as which methods are available to arrays or other objects, should be looked up in the linked class descriptions.

    Identifiers

    Any string that restricts itself to alphabetic characters ( to z and A to Z), digits (0 to 9) and _ qualifies as an identifier. Additionally, identifiers must not begin with a digit. Identifiers are case-sensitive (foo is different from FOO).

    Keywords

    The following is the list of keywords supported by the language. Since keywords are reserved words (tokens), they can’t be used as identifiers. Operators (like in, not, and or or) and names of built-in types as listed in the following sections are also reserved.

    Keywords are defined in the GDScript tokenizer in case you want to take a look under the hood.

    Operators

    The following is the list of supported operators and their precedence.

    Literals

    Integers and floats can have their numbers separated with _ to make them more readable. The following ways to write numbers are all valid:

    1. 12_345_678  # Equal to 12345678.
    2. 3.141_592_7  # Equal to 3.1415927.
    3. 0x8080_0000_ffff  # Equal to 0x80800000ffff.
    4. 0b11_00_11_00  # Equal to 0b11001100.

    Comments

    Anything from a # to the end of the line is ignored and is considered a comment.

    1. # This is a comment.

    Built-in types are stack-allocated. They are passed as values. This means a copy is created on each assignment or when passing them as arguments to functions. The only exceptions are Arrays and Dictionaries, which are passed by reference so they are shared. (Pooled arrays such as PoolByteArray are still passed as values.)

    Basic built-in types

    A variable in GDScript can be assigned to several built-in types.

    null

    null is an empty data type that contains no information and can not be assigned any other value.

    bool

    Short for “boolean”, it can only contain true or false.

    int

    Short for “integer”, it stores whole numbers (positive and negative). It is stored as a 64-bit value, equivalent to “int64_t” in C++.

    float

    Stores real numbers, including decimals, using floating-point values. It is stored as a 64-bit value, equivalent to “double” in C++. Note: Currently, data structures such as Vector2, Vector3, and PoolRealArray store 32-bit single-precision “float” values.

    String

    A sequence of characters in . Strings can contain the following escape sequences:

    GDScript also supports GDScript format strings.

    2D vector type containing x and y fields. Can also be accessed as an array.

    2D Rectangle type containing two vectors fields: position and size. Also contains an end field which is position + size.

    3D vector type containing x, y and z fields. This can also be accessed as an array.

    3×2 matrix used for 2D transforms.

    3D Plane type in normalized form that contains a normal vector field and a d scalar distance.

    Quaternion is a datatype used for representing a 3D rotation. It’s useful for interpolating rotations.

    Axis-aligned bounding box (or 3D box) contains 2 vectors fields: position and size. Also contains an end field which is position + size.

    3x3 matrix used for 3D rotation and scale. It contains 3 vector fields (x, y and z) and can also be accessed as an array of 3D vectors.

    3D Transform contains a Basis field basis and a Vector3 field origin.

    Engine built-in types

    Color

    Color data type contains r, g, b, and a fields. It can also be accessed as h, s, and v for hue/saturation/value.

    NodePath

    Compiled path to a node used mainly in the scene system. It can be easily assigned to, and from, a String.

    RID

    Resource ID (RID). Servers use generic RIDs to reference opaque data.

    Object

    Base class for anything that is not a built-in type.

    Container built-in types

    Generic sequence of arbitrary object types, including other arrays or dictionaries (see below). The array can resize dynamically. Arrays are indexed starting from index 0. Negative indices count from the end.

    1. var arr = []
    2. arr = [1, 2, 3]
    3. var b = arr[1] # This is 2.
    4. var c = arr[arr.size() - 1] # This is 3.
    5. var d = arr[-1] # Same as the previous line, but shorter.
    6. arr[0] = "Hi!" # Replacing value 1 with "Hi!".
    7. arr.append(4) # Array is now ["Hi!", 2, 3, 4].

    GDScript arrays are allocated linearly in memory for speed. Large arrays (more than tens of thousands of elements) may however cause memory fragmentation. If this is a concern, special types of arrays are available. These only accept a single data type. They avoid memory fragmentation and use less memory, but are atomic and tend to run slower than generic arrays. They are therefore only recommended to use for large data sets:

    Associative container which contains values referenced by unique keys.

    1. var d = {4: 5, "A key": "A value", 28: [1, 2, 3]}
    2. d["Hi!"] = 0
    3. d = {
    4.     22: "value",
    5.     "some_key": 2,
    6.     "other_key": [2, 3, 4],
    7.     "more_key": "Hello"
    8. }

    Lua-style table syntax is also supported. Lua-style uses = instead of : and doesn’t use quotes to mark string keys (making for slightly less to write). However, keys written in this form can’t start with a digit (like any GDScript identifier).

    1. var d = {
    2.     test22 = "value",
    3.     some_key = 2,
    4.     other_key = [2, 3, 4],
    5.     more_key = "Hello"
    6. }

    To add a key to an existing dictionary, access it like an existing key and assign to it:

    1. var d = {} # Create an empty Dictionary.
    2. d.waiting = 14 # Add String "waiting" as a key and assign the value 14 to it.
    3. d[4] = "hello" # Add integer 4 as a key and assign the String "hello" as its value.
    4. d["Godot"] = 3.01 # Add String "Godot" as a key and assign the value 3.01 to it.
    6. var test = 4
    7. # Prints "hello" by indexing the dictionary with a dynamic key.
    8. # This is not the same as `d.test`. The bracket syntax equivalent to
    9. # `d.test` is `d["test"]`.
    10. print(d[test])

    Note

    The bracket syntax can be used to access properties of any Object, not just Dictionaries. Keep in mind it will cause a script error when attempting to index a non-existing property. To avoid this, use the and Object.set() methods instead.

    Variables

    Variables can exist as class members or local to functions. They are created with the var keyword and may, optionally, be assigned a value upon initialization.

    1. var a # Data type is 'null' by default.
    2. var b = 5
    3. var c = 3.8
    4. var d = b + c # Variables are always initialized in order.

    Variables can optionally have a type specification. When a type is specified, the variable will be forced to have always that same type, and trying to assign an incompatible value will raise an error.

    Types are specified in the variable declaration using a : (colon) symbol after the variable name, followed by the type.

    1. var my_vector2: Vector2
    2. var my_node: Node = Sprite.new()

    If the variable is initialized within the declaration, the type can be inferred, so it’s possible to omit the type name:

    1. var my_vector2 := Vector2() # 'my_vector2' is of type 'Vector2'.
    2. var my_node := Sprite.new() # 'my_node' is of type 'Sprite'.

    Type inference is only possible if the assigned value has a defined type, otherwise it will raise an error.

    Valid types are:

    • Built-in types (Array, Vector2, int, String, etc.).

    • Engine classes (Node, Resource, Reference, etc.).

    • Constant names if they contain a script resource (MyScript if you declared const MyScript = preload("res://my_script.gd")).

    • Other classes in the same script, respecting scope (InnerClass.NestedClass if you declared class NestedClass inside the class InnerClass in the same scope).

    • Script classes declared with the class_name keyword.

    Casting

    Values assigned to typed variables must have a compatible type. If it’s needed to coerce a value to be of a certain type, in particular for object types, you can use the casting operator as.

    Casting between object types results in the same object if the value is of the same type or a subtype of the cast type.

    1. var my_node2D: Node2D
    2. my_node2D = $Sprite as Node2D # Works since Sprite is a subtype of Node2D.

    If the value is not a subtype, the casting operation will result in a null value.

    1. var my_node2D: Node2D
    2. my_node2D = $Button as Node2D # Results in 'null' since a Button is not a subtype of Node2D.

    For built-in types, they will be forcibly converted if possible, otherwise the engine will raise an error.

    1. var my_int: int
    2. my_int = "123" as int # The string can be converted to int.
    3. my_int = Vector2() as int # A Vector2 can't be converted to int, this will cause an error.

    Casting is also useful to have better type-safe variables when interacting with the scene tree:

    1. # Will infer the variable to be of type Sprite.
    2. var my_sprite := $Character as Sprite
    4. # Will fail if $AnimPlayer is not an AnimationPlayer, even if it has the method 'play()'.
    5. ($AnimPlayer as AnimationPlayer).play("walk")

    Constants

    Constants are values you cannot change when the game is running. Their value must be known at compile-time. Using the const keyword allows you to give a constant value a name. Trying to assign a value to a constant after it’s declared will give you an error.

    We recommend using constants whenever a value is not meant to change.

    1. const A = 5
    2. const B = Vector2(20, 20)
    3. const C = 10 + 20 # Constant expression.
    4. const D = Vector2(20, 30).x # Constant expression: 20.
    5. const E = [1, 2, 3, 4][0] # Constant expression: 1.
    6. const F = sin(20) # 'sin()' can be used in constant expressions.
    7. const G = x + 20 # Invalid; this is not a constant expression!
    8. const H = A + 20 # Constant expression: 25 (`A` is a constant).

    Although the type of constants is inferred from the assigned value, it’s also possible to add explicit type specification:

    1. const A: int = 5
    2. const B: Vector2 = Vector2()

    Assigning a value of an incompatible type will raise an error.

    Note

    Since arrays and dictionaries are passed by reference, constants are “flat”. This means that if you declare a constant array or dictionary, it can still be modified afterwards. They can’t be reassigned with another value though.

    Enums

    Enums are basically a shorthand for constants, and are pretty useful if you want to assign consecutive integers to some constant.

    If you pass a name to the enum, it will put all the keys inside a constant dictionary of that name.

    Important

    In Godot 3.1 and later, keys in a named enum are not registered as global constants. They should be accessed prefixed by the enum’s name (Name.KEY); see an example below.

    1. enum {TILE_BRICK, TILE_FLOOR, TILE_SPIKE, TILE_TELEPORT}
    2. # Is the same as:
    3. const TILE_BRICK = 0
    4. const TILE_FLOOR = 1
    5. const TILE_SPIKE = 2
    6. const TILE_TELEPORT = 3
    8. enum State {STATE_IDLE, STATE_JUMP = 5, STATE_SHOOT}
    9. # Is the same as:
    10. const State = {STATE_IDLE = 0, STATE_JUMP = 5, STATE_SHOOT = 6}
    11. # Access values with State.STATE_IDLE, etc.

    Functions

    Functions always belong to a . The scope priority for variable look-up is: local → class member → global. The self variable is always available and is provided as an option for accessing class members, but is not always required (and should not be sent as the function’s first argument, unlike Python).

    1. func my_function(a, b):
    2.     print(a)
    3.     print(b)
    4.     return a + b  # Return is optional; without it 'null' is returned.

    A function can return at any point. The default return value is null.

    Functions can also have type specification for the arguments and for the return value. Types for arguments can be added in a similar way to variables:

    1. func my_function(a: int, b: String):
    2.     pass

    If a function argument has a default value, it’s possible to infer the type:

    1. func my_function(int_arg := 42, String_arg := "string"):
    2.     pass
    1. func my_int_function() -> int:
    2.     return 0

    Functions that have a return type must return a proper value. Setting the type as void means the function doesn’t return anything. Void functions can return early with the return keyword, but they can’t return any value.

    1. func void_function() -> void:
    2.     return # Can't return a value

    Note

    Non-void functions must always return a value, so if your code has branching statements (such as an if/else construct), all the possible paths must have a return. E.g., if you have a return inside an if block but not after it, the editor will raise an error because if the block is not executed, the function won’t have a valid value to return.

    Referencing functions

    Contrary to Python, functions are not first-class objects in GDScript. This means they cannot be stored in variables, passed as an argument to another function or be returned from other functions. This is for performance reasons.

    To reference a function by name at run-time, (e.g. to store it in a variable, or pass it to another function as an argument) one must use the call or funcref helpers:

    1. # Call a function by name in one step.
    2. my_node.call("my_function", args)
    4. # Store a function reference.
    5. var my_func = funcref(my_node, "my_function")
    6. # Call stored function reference.
    7. my_func.call_func(args)

    Static functions

    A function can be declared static. When a function is static, it has no access to the instance member variables or self. This is mainly useful to make libraries of helper functions:

    1. static func sum2(a, b):
    2.     return a + b

    Statements and control flow

    Statements are standard and can be assignments, function calls, control flow structures, etc (see below). ; as a statement separator is entirely optional.

    if/else/elif

    Simple conditions are created by using the if/else/elif syntax. Parenthesis around conditions are allowed, but not required. Given the nature of the tab-based indentation, elif can be used instead of else/if to maintain a level of indentation.

    1. if [expression]:
    2.     statement(s)
    3. elif [expression]:
    4.     statement(s)
    5. else:
    6.     statement(s)

    Short statements can be written on the same line as the condition:

    Sometimes, you might want to assign a different initial value based on a boolean expression. In this case, ternary-if expressions come in handy:

    1. var x = [value] if [expression] else [value]

    Ternary-if expressions can be nested to handle more than 2 cases. When nesting ternary-if expressions, it is recommended to wrap the complete expression over multiple lines to preserve readability:

    1. var count = 0
    3. var fruit = (
    4.         "apple" if count == 2
    5.         else "pear" if count == 1
    6.         else "banana" if count == 0
    7.         else "orange"
    8. )
    9. print(fruit)  # banana
    11. # Alternative syntax with backslashes instead of parentheses (for multi-line expressions).
    12. # Less lines required, but harder to refactor.
    13. var fruit_alt = \
    14.         "apple" if count == 2 \
    15.         else "pear" if count == 1 \
    16.         else "banana" if count == 0 \
    17.         else "orange"
    18. print(fruit_alt)  # banana

    while

    Simple loops are created by using while syntax. Loops can be broken using break or continued using continue:

    1. while [expression]:

    for

    To iterate through a range, such as an array or table, a for loop is used. When iterating over an array, the current array element is stored in the loop variable. When iterating over a dictionary, the key is stored in the loop variable.

    1. for x in [5, 7, 11]:
    2.     statement # Loop iterates 3 times with 'x' as 5, then 7 and finally 11.
    4. var dict = {"a": 0, "b": 1, "c": 2}
    5. for i in dict:
    6.     print(dict[i]) # Prints 0, then 1, then 2.
    8. for i in range(3):
    9.     statement # Similar to [0, 1, 2] but does not allocate an array.
    11. for i in range(1, 3):
    12.     statement # Similar to [1, 2] but does not allocate an array.
    14. for i in range(2, 8, 2):
    15.     statement # Similar to [2, 4, 6] but does not allocate an array.
    17. for c in "Hello":
    18.     print(c) # Iterate through all characters in a String, print every letter on new line.
    20. for i in 3:
    21.     statement # Similar to range(3)
    23. for i in 2.2:
    24.     statement # Similar to range(ceil(2.2))

    match

    A match statement is used to branch execution of a program. It’s the equivalent of the switch statement found in many other languages, but offers some additional features.

    Basic syntax:

    1. match [expression]:
    2.     [pattern](s):
    3.         [block]
    4.     [pattern](s):
    5.         [block]
    6.     [pattern](s):
    7.         [block]

    Crash-course for people who are familiar with switch statements:

    1. Replace switch with match.

    2. Remove case.

    3. Remove any breaks. If you don’t want to break by default, you can use continue for a fallthrough.

    4. Change default to a single underscore.

    Control flow:

    The patterns are matched from top to bottom. If a pattern matches, the first corresponding block will be executed. After that, the execution continues below the match statement. You can use continue to stop execution in the current block and check for an additional match in the patterns below it.

    There are 6 pattern types:

    • Constant pattern

      Constant primitives, like numbers and strings:

      1. match x:
      2.     1:
      3.         print("We are number one!")
      4.     2:
      5.         print("Two are better than one!")
      6.     "test":
      7.         print("Oh snap! It's a string!")

    • Variable pattern

      Matches the contents of a variable/enum:

      1. match typeof(x):
      2.     TYPE_REAL:
      3.         print("float")
      4.     TYPE_STRING:
      5.         print("text")
      6.     TYPE_ARRAY:
      7.         print("array")

    • Wildcard pattern

      This pattern matches everything. It’s written as a single underscore.

      It can be used as the equivalent of the default in a switch statement in other languages:

      1. match x:
      2.     1:
      3.         print("It's one!")
      4.     2:
      5.         print("It's one times two!")
      6.     _:
      7.         print("It's not 1 or 2. I don't care to be honest.")

    • Binding pattern

      A binding pattern introduces a new variable. Like the wildcard pattern, it matches everything - and also gives that value a name. It’s especially useful in array and dictionary patterns:

      1. match x:
      2.     1:
      3.         print("It's one!")
      4.     2:
      5.         print("It's one times two!")
      6.     var new_var:
      7.         print("It's not 1 or 2, it's ", new_var)

    • Array pattern

      Matches an array. Every single element of the array pattern is a pattern itself, so you can nest them.

      The length of the array is tested first, it has to be the same size as the pattern, otherwise the pattern doesn’t match.

      Open-ended array: An array can be bigger than the pattern by making the last subpattern ...

      Every subpattern has to be comma-separated.

      1. match x:
      2.     []:
      3.         print("Empty array")
      4.     [1, 3, "test", null]:
      5.         print("Very specific array")
      6.     [var start, _, "test"]:
      7.         print("First element is ", start, ", and the last is \"test\"")
      8.     [42, ..]:
      9.         print("Open ended array")

    • Dictionary pattern

      Works in the same way as the array pattern. Every key has to be a constant pattern.

      The size of the dictionary is tested first, it has to be the same size as the pattern, otherwise the pattern doesn’t match.

      Open-ended dictionary: A dictionary can be bigger than the pattern by making the last subpattern ...

      Every subpattern has to be comma separated.

      If you don’t specify a value, then only the existence of the key is checked.

      A value pattern is separated from the key pattern with a :.

      1. match x:
      2.     {}:
      3.         print("Empty dict")
      4.     {"name": "Dennis"}:
      5.         print("The name is Dennis")
      6.     {"name": "Dennis", "age": var age}:
      7.         print("Dennis is ", age, " years old.")
      8.     {"name", "age"}:
      9.         print("Has a name and an age, but it's not Dennis :(")
      10.     {"key": "godotisawesome", ..}:
      11.         print("I only checked for one entry and ignored the rest")

    • Multiple patterns

      You can also specify multiple patterns separated by a comma. These patterns aren’t allowed to have any bindings in them.

      1. match x:
      2.     1, 2, 3:
      3.         print("It's 1 - 3")
      4.     "Sword", "Splash potion", "Fist":
      5.         print("Yep, you've taken damage")

    Classes

    By default, all script files are unnamed classes. In this case, you can only reference them using the file’s path, using either a relative or an absolute path. For example, if you name a script file character.gd:

    1. # Inherit from 'Character.gd'.
    3. extends "res://path/to/character.gd"
    5. # Load character.gd and create a new node instance from it.
    7. var Character = load("res://path/to/character.gd")
    8. var character_node = Character.new()

    You can give your class a name to register it as a new type in Godot’s editor. For that, you use the class_name keyword. You can optionally add a comma followed by a path to an image, to use it as an icon. Your class will then appear with its new icon in the editor:

    1. # Item.gd
    3. extends Node
    4. class_name Item, "res://interface/icons/item.png"

    Warning

    If the script is located in the res://addons/ directory, class_name will only cause the node to show up in the Create New Node dialog if the script is part of an enabled editor plugin. See for more information.

    Here’s a class file example:

    1. # Saved as a file named 'character.gd'.
    3. class_name Character
    6. var health = 5
    9. func print_health():
    10.     print(health)
    13. func print_this_script_three_times():
    14.     print(get_script())
    15.     print(ResourceLoader.load("res://character.gd"))
    16.     print(Character)

    Note

    Godot’s class syntax is compact: it can only contain member variables or functions. You can use static functions, but not static member variables. In the same way, the engine initializes variables every time you create an instance, and this includes arrays and dictionaries. This is in the spirit of thread safety, since scripts can be initialized in separate threads without the user knowing.

    Inheritance

    A class (stored as a file) can inherit from:

    • A global class.

    • Another class file.

    • An inner class inside another class file.

    Multiple inheritance is not allowed.

    Inheritance uses the extends keyword:

    1. # Inherit/extend a globally available class.
    2. extends SomeClass
    4. # Inherit/extend a named class file.
    5. extends "somefile.gd"
    7. # Inherit/extend an inner class in another file.
    8. extends "somefile.gd".SomeInnerClass

    To check if a given instance inherits from a given class, the is keyword can be used:

    1. # Cache the enemy class.
    2. const Enemy = preload("enemy.gd")
    4. # [...]
    6. # Use 'is' to check inheritance.
    7. if entity is Enemy:
    8.     entity.apply_damage()

    To call a function in a parent class (i.e. one extend-ed in your current class), prepend . to the function name:

    1. .base_func(args)

    This is especially useful because functions in extending classes replace functions with the same name in their parent classes. If you still want to call them, you can prefix them with . (like the super keyword in other languages):

    1. func some_func(x):
    2.     .some_func(x) # Calls the same function on the parent class.

    Note

    Default functions like _init, and most notifications such as _enter_tree, _exit_tree, _process, _physics_process, etc. are called in all parent classes automatically. There is no need to call them explicitly when overloading them.

    Class constructor

    The class constructor, called on class instantiation, is named _init. As mentioned earlier, the constructors of parent classes are called automatically when inheriting a class. So, there is usually no need to call ._init() explicitly.

    Unlike the call of a regular function, like in the above example with .some_func, if the constructor from the inherited class takes arguments, they are passed like this:

    1. func _init(args).(parent_args):
    2.    pass

    This is better explained through examples. Consider this scenario:

    1. # State.gd (inherited class)
    2. var entity = null
    3. var message = null
    6. func _init(e=null):
    7.     entity = e
    10. func enter(m):
    11.     message = m
    14. # Idle.gd (inheriting class)
    15. extends "State.gd"
    18. func _init(e=null, m=null).(e):
    19.     # Do something with 'e'.
    20.     message = m

    There are a few things to keep in mind here:

    1. If the inherited class (State.gd) defines a _init constructor that takes arguments (e in this case), then the inheriting class (Idle.gd) must define _init as well and pass appropriate parameters to _init from State.gd.

    2. Idle.gd can have a different number of arguments than the parent class State.gd.

    3. In the example above, e passed to the State.gd constructor is the same e passed in to Idle.gd.

    4. If Idle.gd‘s _init constructor takes 0 arguments, it still needs to pass some value to the State.gd parent class, even if it does nothing. This brings us to the fact that you can pass literals in the base constructor as well, not just variables, e.g.:

      1. # Idle.gd
      3. func _init().(5):
      4.     pass

    Inner classes

    A class file can contain inner classes. Inner classes are defined using the class keyword. They are instanced using the ClassName.new() function.

    1. # Inside a class file.
    3. # An inner class in this class file.
    4. class SomeInnerClass:
    5.     var a = 5
    8.     func print_value_of_a():
    9.         print(a)
    12. # This is the constructor of the class file's main class.
    13. func _init():
    14.     var c = SomeInnerClass.new()
    15.     c.print_value_of_a()

    Classes as resources

    Classes stored as files are treated as resources. They must be loaded from disk to access them in other classes. This is done using either the load or preload functions (see below). Instancing of a loaded class resource is done by calling the new function on the class object:

    1. # Load the class resource when calling load().
    2. var MyClass = load("myclass.gd")
    4. # Preload the class only once at compile time.
    5. const MyClass = preload("myclass.gd")
    8. func _init():
    9.     var a = MyClass.new()

    Exports

    Note

    Documentation about exports has been moved to GDScript exports.

    Setters/getters

    It is often useful to know when a class’ member variable changes for whatever reason. It may also be desired to encapsulate its access in some way.

    For this, GDScript provides a setter/getter syntax using the setget keyword. It is used directly after a variable definition:

    Whenever the value of variable is modified by an external source (i.e. not from local usage in the class), the setter function (setterfunc above) will be called. This happens before the value is changed. The setter must decide what to do with the new value. Vice versa, when variable is accessed, the getter function (getterfunc above) must return the desired value. Below is an example:

    1. var my_var setget my_var_set, my_var_get
    4. func my_var_set(new_value):
    5.     my_var = new_value
    8. func my_var_get():
    9.     return my_var # Getter must return a value.

    Either of the setter or getter functions can be omitted:

    1. # Only a setter.
    2. var my_var = 5 setget my_var_set
    3. # Only a getter (note the comma).
    4. var my_var = 5 setget ,my_var_get

    Setters and getters are useful when exporting variables to the editor in tool scripts or plugins, for validating input.

    As said, local access will not trigger the setter and getter. Here is an illustration of this:

    1. func _init():
    2.     # Does not trigger setter/getter.
    3.     my_integer = 5
    4.     print(my_integer)
    6.     # Does trigger setter/getter.
    7.     self.my_integer = 5
    8.     print(self.my_integer)

    Tool mode

    By default, scripts don’t run inside the editor and only the exported properties can be changed. In some cases, it is desired that they do run inside the editor (as long as they don’t execute game code or manually avoid doing so). For this, the tool keyword exists and must be placed at the top of the file:

    1. tool
    2. extends Button
    5. func _ready():
    6.     print("Hello")

    See Running code in the editor for more information.

    Warning

    Be cautious when freeing nodes with queue_free() or free() in a tool script (especially the script’s owner itself). As tool scripts run their code in the editor, misusing them may lead to crashing the editor.

    Memory management

    If a class inherits from Reference, then instances will be freed when no longer in use. No garbage collector exists, just reference counting. By default, all classes that don’t define inheritance extend Reference. If this is not desired, then a class must inherit manually and must call instance.free(). To avoid reference cycles that can’t be freed, a WeakRef function is provided for creating weak references. Here is an example:

    1. extends Node
    3. var my_node_ref
    5. func _ready():
    6.     my_node_ref = weakref(get_node("MyNode"))
    8. func _this_is_called_later():
    9.     var my_node = my_node_ref.get_ref()
    10.     if my_node:
    11.         my_node.do_something()

    Alternatively, when not using references, the is_instance_valid(instance) can be used to check if an object has been freed.

    Signals

    Signals are a tool to emit messages from an object that other objects can react to. To create custom signals for a class, use the signal keyword.

    1. extends Node
    4. # A signal named health_depleted.
    5. signal health_depleted

    Note

    Signals are a Callback) mechanism. They also fill the role of Observers, a common programming pattern. For more information, read the in the Game Programming Patterns ebook.

    You can connect these signals to methods the same way you connect built-in signals of nodes like Button or .

    In the example below, we connect the health_depleted signal from a Character node to a Game node. When the Character node emits the signal, the game node’s _on_Character_health_depleted is called:

    1. # Game.gd
    3. func _ready():
    4.     var character_node = get_node('Character')
    5.     character_node.connect("health_depleted", self, "_on_Character_health_depleted")
    8. func _on_Character_health_depleted():
    9.     get_tree().reload_current_scene()

    You can emit as many arguments as you want along with a signal.

    Here is an example where this is useful. Let’s say we want a life bar on screen to react to health changes with an animation, but we want to keep the user interface separate from the player in our scene tree.

    In our Character.gd script, we define a health_changed signal and emit it with Object.emit_signal(), and from a Game node higher up our scene tree, we connect it to the Lifebar using the method:

    1. # Character.gd
    3. ...
    4. signal health_changed
    7. func take_damage(amount):
    8.     var old_health = health
    9.     health -= amount
    11.     # We emit the health_changed signal every time the
    12.     # character takes damage.
    13.     emit_signal("health_changed", old_health, health)
    14. ...
    1. # Lifebar.gd
    3. # Here, we define a function to use as a callback when the
    4. # character's health_changed signal is emitted.
    6. ...
    7. func _on_Character_health_changed(old_value, new_value):
    8.     if old_value > new_value:
    9.         progress_bar.modulate = Color.red
    10.     else:
    11.         progress_bar.modulate = Color.green
    13.     # Imagine that `animate` is a user-defined function that animates the
    14.     # bar filling up or emptying itself.
    15.     progress_bar.animate(old_value, new_value)
    16. ...

    Note

    To use signals, your class has to extend the Object class or any type extending it like Node, KinematicBody, Control…

    In the Game node, we get both the Character and Lifebar nodes, then connect the character, that emits the signal, to the receiver, the Lifebar node in this case.

    1. # Game.gd
    3. func _ready():
    4.     var character_node = get_node('Character')
    5.     var lifebar_node = get_node('UserInterface/Lifebar')
    7.     character_node.connect("health_changed", lifebar_node, "_on_Character_health_changed")

    This allows the Lifebar to react to health changes without coupling it to the Character node.

    You can write optional argument names in parentheses after the signal’s definition:

    1. # Defining a signal that forwards two arguments.
    2. signal health_changed(old_value, new_value)

    These arguments show up in the editor’s node dock, and Godot can use them to generate callback functions for you. However, you can still emit any number of arguments when you emit signals; it’s up to you to emit the correct values.

    ../../../_images/gdscript_basics_signals_node_tab_1.png

    GDScript can bind an array of values to connections between a signal and a method. When the signal is emitted, the callback method receives the bound values. These bound arguments are unique to each connection, and the values will stay the same.

    You can use this array of values to add extra constant information to the connection if the emitted signal itself doesn’t give you access to all the data that you need.

    Building on the example above, let’s say we want to display a log of the damage taken by each character on the screen, like Player1 took 22 damage.. The health_changed signal doesn’t give us the name of the character that took damage. So when we connect the signal to the in-game console, we can add the character’s name in the binds array argument:

    1. # Game.gd
    3. func _ready():
    4.     var character_node = get_node('Character')
    5.     var battle_log_node = get_node('UserInterface/BattleLog')
    7.     character_node.connect("health_changed", battle_log_node, "_on_Character_health_changed", [character_node.name])

    Our BattleLog node receives each element in the binds array as an extra argument:

    1. # BattleLog.gd
    3. func _on_Character_health_changed(old_value, new_value, character_name):
    4.     if not new_value <= old_value:
    5.         return
    7.     var damage = old_value - new_value
    8.     label.text += character_name + " took " + str(damage) + " damage."

    Coroutines with yield

    GDScript offers support for via the yield built-in function. Calling yield() will immediately return from the current function, with the current frozen state of the same function as the return value. Calling resume() on this resulting object will continue execution and return whatever the function returns. Once resumed, the state object becomes invalid. Here is an example:

    1. func my_func():
    2.     print("Hello")
    3.     yield()
    4.     print("world")
    7. func _ready():
    8.     var y = my_func()
    9.     # Function state saved in 'y'.
    10.     print("my dear")
    11.     y.resume()
    12.     # 'y' resumed and is now an invalid state.

    Will print:

    1. Hello
    2. my dear
    3. world

    It is also possible to pass values between yield() and resume(), for example:

    1. func my_func():
    2.     print("Hello")
    3.     print(yield())
    4.     return "cheers!"
    7. func _ready():
    8.     var y = my_func()
    9.     # Function state saved in 'y'.
    10.     print(y.resume("world"))
    11.     # 'y' resumed and is now an invalid state.

    Will print:

    1. Hello
    2. world
    3. cheers!

    Remember to save the new function state, when using multiple yields:

    1. func co_func():
    2.     for i in range(1, 5):
    3.         print("Turn %d" % i)
    4.         yield();
    7. func _ready():
    8.     var co = co_func();
    9.     while co is GDScriptFunctionState && co.is_valid():
    10.         co = co.resume();

    Coroutines & signals

    The real strength of using yield is when combined with signals. yield can accept two arguments, an object and a signal. When the signal is received, execution will recommence. Here are some examples:

    1. # Resume execution the next frame.
    2. yield(get_tree(), "idle_frame")
    4. # Resume execution when animation is done playing.
    5. yield(get_node("AnimationPlayer"), "animation_finished")
    7. # Wait 5 seconds, then resume execution.
    8. yield(get_tree().create_timer(5.0), "timeout")

    Coroutines themselves use the completed signal when they transition into an invalid state, for example:

    1. func my_func():
    2.     yield(button_func(), "completed")
    3.     print("All buttons were pressed, hurray!")
    6. func button_func():
    7.     yield($Button0, "pressed")
    8.     yield($Button1, "pressed")

    my_func will only continue execution once both buttons have been pressed.

    You can also get the signal’s argument once it’s emitted by an object:

    1. # Wait for when any node is added to the scene tree.
    2. var node = yield(get_tree(), "node_added")

    If there is more than one argument, yield returns an array containing the arguments:

    1. signal done(input, processed)
    3. func process_input(input):
    4.     print("Processing initialized")
    5.     yield(get_tree(), "idle_frame")
    6.     print("Waiting")
    7.     yield(get_tree(), "idle_frame")
    8.     emit_signal("done", input, "Processed " + input)
    11. func _ready():
    12.     process_input("Test") # Prints: Processing initialized
    13.     var data = yield(self, "done") # Prints: waiting
    14.     print(data[1]) # Prints: Processed Test

    If you’re unsure whether a function may yield or not, or whether it may yield multiple times, you can yield to the completed signal conditionally:

    1. func generate():
    2.     var result = rand_range(-1.0, 1.0)
    4.     if result < 0.0:
    5.         yield(get_tree(), "idle_frame")
    7.     return result
    10. func make():
    11.     var result = generate()
    13.     if result is GDScriptFunctionState: # Still working.
    14.         result = yield(result, "completed")
    16.     return result

    This ensures that the function returns whatever it was supposed to return regardless of whether coroutines were used internally. Note that using while would be redundant here as the completed signal is only emitted when the function didn’t yield anymore.

    onready keyword

    When using nodes, it’s common to desire to keep references to parts of the scene in a variable. As scenes are only warranted to be configured when entering the active scene tree, the sub-nodes can only be obtained when a call to Node._ready() is made.

    1. var my_label
    4. func _ready():
    5.     my_label = get_node("MyLabel")

    This can get a little cumbersome, especially when nodes and external references pile up. For this, GDScript has the onready keyword, that defers initialization of a member variable until _ready() is called. It can replace the above code with a single line:

    1. # Check that 'i' is 0. If 'i' is not 0, an assertion error will occur.

    When running a project from the editor, the project will be paused if an assertion error occurs.